Adobe Flash. Создание аркад, головоломок и других игр с помощью ActionScript

Розенцвейг Гэри

Сценарий кнопки устанавливает координаты клипа «Color Selection», то есть рамки, равными координатам клипа, по которому щелкнул пользователь. При этом вокруг кнопки с выбранным цветом появится контур (рис. 7.6). Маленькая кнопка с кружочком посередине служит для выбора режима рисования – с заливкой или без. Клип с этой кнопкой состоит из двух кадров: с пустым и заполненным кружочком. Кнопка содержит сценарий, позволяющий переключаться между кадрами, и определяет переменную fill клипа «actions».

on (release) {

if (_currentFrame == 1) {

gotoAndStop(2);

_root.actions.fill = true;

} else {

gotoAndStop(1);

_root.actions.fill = false;

}

}

С

помощью кнопок, определяющих цвета, и кнопки выбора режима (с заливкой/без заливки) пользователь может рисовать разноцветные фигуры. Как и в предыдущем примере, код, необходимый для рисования, содержится в клипе «actions». Он начинается с определения значения следующих переменных: draw – false, fill – false, lineColor – 0x000000. Также определяются четыре переменные для которые ограничивают область в которой пользователь может рисовать.

onClipEvent (load) {

// Рисовать или не рисовать?

draw = false;

// Определяем значение fill.

fill = false;

// Начальный цвет линии – черный.

lineColor = 0x000000;

// Определяем границы области рисования.

xmax = 550;

xmin = 70;

ymax = 400;

ymin = 0;

}

При нажатии кнопки мыши курсор начинает оставлять след. Координаты курсора хранятся в переменных x и у. Их значения проверяются, и, если они выходят за границы разрешенной области, рисование не происходит. Переменная lineColor передается функции lineStyle в качестве аргумента, определяющего цвет линии. Если переменная fill имеет значение true, то определяется новый массив. Он содержит координаты всех точек вдоль кривой, которую нарисовал пользователь. Массив состоит из объектов следующего вида: {x: значение, у: значение}. Элементы массива потребуются для создания залитой цветом области.

onClipEvent (mouseDown) {

// Определяем позицию курсора.

x = _root._xmouse;

y = _root._ymouse;

// Рисуем, если не вышли за границы поля.

if ((x>xmin) and (x<xmax) and (y>ymin) and (y<ymax)) {

draw = true;

// Определяем параметры линии.

_root.lineStyle(1,lineColor,100);

_root.moveTo(x,y);

// Если выбран режим заливки, то создаем массив.

if (fill) {

fillArray = new Array;

fillArray.push({x:x, y:y});

}

}

}

После того как переменной draw присвоено значение true, продолжаем линию до тех пор, пока пользователь не отпустит кнопку мыши. При каждом обращении к кадру переменным x и у присваиваются текущие координаты курсора. Если эти значения выходят за разрешенные границы, переменные x и у переопределяются. Затем используется команда lineTo для отображения очередного сегмента линии. Если выбран режим заливки, то добавляется новый элемент в массив fillArray.

onClipEvent (enterFrame) {

if (draw) {

// Определяем текущую позицию.

x = _root._xmouse;

y = _root._ymouse;

// Задаем границы области рисования.

if (x < xmin) x = xmin;

if (x > xmax) x = xmax;

if (y < ymin) y = ymin;

if (y > ymax) y = ymax;

//

Рисуем линию.

_root.lineTo(x,y);

// Если выбран режим заливки, то запоминаем точку.

if (fill) {

fillArray.push({x:x, y:y});

}

}

}

Когда пользователь отпускает кнопку мыши, переменная draw принимает, значение false, и рисование прекращается. Если при этом выбран режим заливки, то в цикле просматривается массив fillArray и созданная область перерисовывается. При этом также используются команды beginFill и endFill. В результате область заливается цветом lineColor.

onClipEvent (mouseUp) {

if (draw) {

// Прекращаем рисовать.

draw = false;

// Перерисовываем кривую и заливаем

// получившуюся область.

if (fill) {

// Начинаем с первой точки.

_root.moveTo(fillArray[0].x,fillArray[0].y);

// В цикле определяем область для заливки.

_root.beginFill(lineColor);

for(var i=1;i<fillArray.length;i++) {

_root.lineTo(fillArray[i].x,fillArray[i].y);

}

_root.endFill;

}

}

}

...

Внимание!

Другой способ состоит в том, что вы можете вызвать команду beginFill до того, как пользователь начнет рисовать, и команду endFill – когда он закончит, вместо того чтобы перерисовывать кривую. Но Flash не очень любит использовать заливку при разных обращениях к кадру, и результат может быть хаотичен. Лучше сохранить кривую, а затем перерисовать ее и создать всю заливку в пределах одного обработчика.

Добавление кнопок Clear и Print

Чтобы очистить рабочую область, мы просто нарисуем сверху заполненный цветом области прямоугольник. Это выполняется с помощью сценария кнопки Clear (Очистить).

Мы устанавливаем толщину линии 0. Затем перемещаем указатель в верхний левый угол нашей области и рисуем прямоугольник, который точно ее повторяет и определяет область заливки. Цвет заливки – белый, так как именно он выбран фоновым в нашем ролике.

on (release) {

// Толщина линии – ноль.

_root.lineStyle(0,0xFFFFFF,100);

// Перемещаем указатель в верхний левый угол.

_root.moveTo(actions.xmin,actions.ymin);

// Создаем область заливки.

_root.beginFill(0xFFFFFF);

_root.lineTo(actions.xmax,actions.ymin);

_root.lineTo(actions.xmax,actions.ymax);

_root.lineTo(actions.xmin,actions.ymax);

_root.lineTo(actions.xmin,actions.ymin);

_root.endFill;

}

Еще легче создать кнопку Print (Печать). Для этого необходимо добавить команду print. Осталось еще присвоить метку «#p» единственному кадру ролика.

on (release) {

// Распечатываем клип.

print(_root,"bframe");

}

...

Примечание

Команда print выводит заданный клип на печать. Добавив к команде слева _root, вы можете напечатать все содержимое рабочего поля. Второй параметр определяет границы области печати. Подробности вы найдете в руководстве пользователя Flash.